Справочник MQL4

FileWriteDouble

Записывает в файл значение параметра типа double с текущего положения файлового указателя.

uint  FileWriteDouble(
   int     file_handle,       // handle файла
   double  value,             // значение для записи
   int     size=DOUBLE_VALUE  // кол-во байт
   );

Параметры

file_handle

[in]  Файловый описатель, возвращаемый функцией FileOpen().

value

[in]  Значение типа double.

size=DOUBLE_VALUE

[in]  Количество байт (до 8 включительно), которые нужно записать. Предусмотрены константы: DOUBLE_VALUE=8, FLOAT_VALUE=4, таким образом, функция может записать значение типа double или float.

Возвращаемое значение

В случае удачи функция возвращает количество записанных байт или 0 в случае ошибки. При успешном завершении количество записанных байт равно размеру типа данных (sizeof(double)=8). Чтобы получить информацию об ошибке, необходимо вызвать функцию GetLastError(). Файловый указатель перемещается на это же количество байт.

Пример:

//+------------------------------------------------------------------+
//|                                         Demo_FileWriteDouble.mq4 |
//|                        Copyright 2014, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2014, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- параметры для получения данных из терминала
input string             InpSymbolName="EURUSD";           // Валютная пара
input ENUM_TIMEFRAMES    InpSymbolPeriod=PERIOD_H1;        // Таймфрейм
input int                InpMAPeriod=10;                   // Период сглаживания
input int                InpMAShift=0;                     // Смещение индикатора
input ENUM_MA_METHOD     InpMAMethod=MODE_SMA;             // Тип сглаживания
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE;      // Тип цены
//--- параметры для записи данных в файл
input string             InpFileName="MA.bin";             // Имя файла
input string             InpDirectoryName="Data";          // Имя каталога
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date_finish=TimeCurrent();
   double   ma_buff[];
   datetime time_buff[];
   int      size;
//--- установим для массивов признак таймсерии
   ArraySetAsSeries(ma_buff,true);
   ArraySetAsSeries(time_buff,true);
//--- сбросим код ошибки
   ResetLastError();
//--- скопируем таймсерию,содержащую время открытия последних 1000 баров
   int copied=CopyTime(NULL,0,0,1000,time_buff);
   if(copied<=0)
     {
      Print("Не удалось скопировать времена открытия за последние 1000 баров");
      return;
     }
//--- подготовим массив ma_buff
   ArrayResize(ma_buff,copied);
//--- скопируем значения индикатора iMA
   for(int i=0;i<copied;i++)
     {
      ma_buff[i]=iMA(InpSymbolName,InpSymbolPeriod,InpMAPeriod,InpMAShift,InpMAMethod,InpAppliedPrice,i);
     }
//---
   PrintFormat("В файл будут записаны значения индикатора, начиная с %s по %s",TimeToString(time_buff[copied-1]),TimeToString(time_buff[0]));
//--- получим размер буфера
   size=ArraySize(ma_buff);
//--- откроем файл для записи значений индикатора (если его нет, то создастся автоматически)
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("Файл %s открыт для записи",InpFileName);
      PrintFormat("Путь к файлу: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- сначала запишем размер выборки данных
      uint byteswritten=FileWriteDouble(file_handle,(double)size,DOUBLE_VALUE);
      //--- проверка количества записанных данных
      if(byteswritten!=sizeof(double))
        {
         PrintFormat("Ошибка записи данных. Код ошибки=%d",GetLastError());
         //--- закрываем файл
         FileClose(file_handle);
         return;
        }
      //--- запишем время и значения индикатора в файл
      for(int i=0;i<size;i++)
        {
         byteswritten=FileWriteDouble(file_handle,(double)time_buff[i],DOUBLE_VALUE);
         //--- проверка количества записанных данных
         if(byteswritten!=sizeof(double))
           {
            PrintFormat("Ошибка записи данных. Код ошибки=%d",GetLastError());
            //--- закрываем файл
            FileClose(file_handle);
            return;
           }
         byteswritten=FileWriteDouble(file_handle,ma_buff[i],DOUBLE_VALUE);
         //--- проверка количества записанных данных
         if(byteswritten!=sizeof(double))
           {
            PrintFormat("Ошибка записи данных. Код ошибки=%d",GetLastError());
            //--- закрываем файл
            FileClose(file_handle);
            return;
           }
        }
      //--- закрываем файл
      FileClose(file_handle);
      PrintFormat("Данные записаны, файл %s закрыт",InpFileName);
     }
   else
      PrintFormat("Не удалось открыть файл %s, Код ошибки = %d",InpFileName,GetLastError());
  }

Смотри также

Вещественные типы (double, float)