Справочник MQL4

FileReadInteger

Читает из бинарного файла значение типа int, short или char в зависимости от указанной длины в байтах. Чтение производится с текущего положения файлового указателя.

int  FileReadInteger(
   int  file_handle,        // handle файла
   int  size=INT_VALUE      // кол-во байт
   );

Параметры

file_handle

[in]  Файловый описатель, возвращаемый функцией FileOpen().

size=INT_VALUE

[in]  Количество байт (до 4 включительно), которые нужно прочитать. Предусмотрены соответствующие константы: CHAR_VALUE=1, SHORT_VALUE=2 и INT_VALUE (LONG_VALUE)=4, таким образом функция может прочитать целое значение типа char, short, int, uint и long.

Возвращаемое значение

Значение типа int. Результат этой функции необходимо явно приводить к целевому типу, то есть тому типу данных, который требуется прочитать. Так как возвращается значение типа int, то его можно спокойно преобразовать в любое целое значение. Файловый указатель перемещается на количество считываемых байт.

Примечание

При чтении менее 4-х байт, полученный результат всегда будет положительным. Если читается один или два байта, то знак числа можно точно определить путем явного приведения соответственно к типу char (1 байт) или типу short (2 байта). Получение знака для трехбайтового числа является нетривиальным, так как нет соответствующего базового типа.

Пример (используется файл, полученный в результате работы примера для функции FileWriteInteger())

//+------------------------------------------------------------------+
//|                                         Demo_FileReadInteger.mq4 |
//|                        Copyright 2014, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2014, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict
#property indicator_chart_window
#property indicator_buffers 1
//---- plot Label1
#property indicator_label1  "Trends"
#property indicator_type1   DRAW_SECTION
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2
//--- параметры для чтения данных
input string InpFileName="Trend.bin"// Имя файла
input string InpDirectoryName="Data"// Имя каталога
//--- глобальные переменные
int      ind=0;
int      size=0;
datetime time_buff[];
//--- indicator buffers
double   buff[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
   int def_size=100;
//--- выделим память для массива
   ArrayResize(time_buff,def_size);
//--- откроем файл
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("Файл %s открыт для чтения",InpFileName);
      PrintFormat("Путь к файлу: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- вспомогательные переменные
      int    arr_size;
      uchar  arr[];
      //--- прочитаем данные из файла
      while(!FileIsEnding(file_handle))
        {
         //--- узнаем сколько символов использовано для записи времени
         arr_size=FileReadInteger(file_handle,INT_VALUE);
         ArrayResize(arr,arr_size);
         for(int i=0;i<arr_size;i++)
            arr[i]=(char)FileReadInteger(file_handle,CHAR_VALUE);
         //--- запомним значение времени
         time_buff[size]=StringToTime(CharArrayToString(arr));
         size++;
         //--- увеличим размеры массивов если они переполнены
         if(size==def_size)
           {
            def_size+=100;
            ArrayResize(time_buff,def_size);
           }
        }
      //--- закроем файл
      FileClose(file_handle);
      PrintFormat("Данные прочитаны, файл %s закрыт",InpFileName);
     }
   else
     {
      PrintFormat("Не удалось открыть файл %s, Код ошибки = %d",InpFileName,GetLastError());
      return(INIT_FAILED);
     }
//--- привязка массива к индикаторному буферу с индексом 0
   SetIndexBuffer(0,buff,INDICATOR_DATA);
//--- установка значений индикатора, которые не будут видимы на графике
   SetIndexEmptyValue(0,0.0);
//--- установка индексации как в таймсерии
   ArraySetAsSeries(time_buff,true);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   ArraySetAsSeries(time,true);
   ArraySetAsSeries(close,true);
//--- цикл для еще необработанных баров
   for(int i=prev_calculated;i<rates_total;i++)
     {
      //--- по умолчанию 0
      buff[i]=0;
      for(int j=0;j<size;j++)
        {
         //--- если даты совпадают, то используем цену close
         if(time[i]==time_buff[j])
           {
            //--- получим цену
            buff[i]=close[i];
           }
        }
     }
//---
   return(rates_total);
  }

Смотри также

IntegerToString(), StringToInteger(), Целые типы, FileWriteInteger()